Posts Tagged ‘ Query

Dynamics Ax 2012 Valid Time State 2

Merhaba

Önceki yazımda  tarih kontrollü yapının nasıl kurulacağını anlatmıştım. Bu yazımda framework ile gelen sorgu özelliklerinden bahsedeceğim. Resimdeki gibi bir örnek verimiz olsun.

Birinci örneğimiz bu gün için geçerli olan sözleşme kaydını bize verir.

Select ile;

static void FD_ValidTimeState1(Args _args)
{
    FDcontractTable   FDcontractTable;
    TransDate         contractStartDate = systemDateGet() ;
    ;

    while select validTimeState(contractStartDate) FDcontractTable
        where FDcontractTable.ContractId == 'CNRT_004'
    {
        info(strFmt("%1: %2 - %3",
            FDcontractTable.ContractId,
            FDcontractTable.ValidFrom,
            FDcontractTable.ValidTo));
    }
}

Query ile;

static void FD_ValidTimeState3(Args _args)
{
    Query               query;
    QueryRun            queryRun;
    FDcontractTable     FDcontractTable;
    TransDate           contractStartDate = systemDateGet() ;
    ;
    query = new Query();
    query.addDataSource(tableNum(FDcontractTable)).addRange(fieldNum(FDcontractTable,
            ContractId)).value(queryValue('CNRT_004'));

    query.validTimeStateAsOfDate(contractStartDate);

    queryRun = new QueryRun(query);

    if(queryRun.prompt())
    {
        while(queryRun.next())
        {
            FDcontractTable = queryRun.getNo(1);
            info(strFmt("%1: %2 - %3",
                FDcontractTable.ContractId,
                FDcontractTable.ValidFrom,
                FDcontractTable.ValidTo));
        }
    }
}

İkinci örnekte ise 30 günlük aralıkta kalan bütün sözleşmeleri  verir.

Select ile;

static void FD_ValidTimeState2(Args _args)
{
    FDcontractTable   FDcontractTable;
    TransDate         contractStartDate = systemDateGet() ;
    TransDate         contractEndDate   = systemDateGet() + 30;
    ;

    while select validTimeState(contractStartDate ,  contractEndDate)
        FDcontractTable
        where FDcontractTable.ContractId == 'CNRT_004'
    {
        info(strFmt("%1: %2 - %3",
            FDcontractTable.ContractId,
            FDcontractTable.ValidFrom,
            FDcontractTable.ValidTo));
    }
}

Query ile;

static void FD_ValidTimeState4(Args _args)
{
    Query               query;
    QueryRun            queryRun;
    FDcontractTable     FDcontractTable;
    TransDate           contractStartDate = systemDateGet() ;
    TransDate           contractEndDate   = systemDateGet() + 30;

    query = new Query();
    query.addDataSource(tableNum(FDcontractTable)).addRange(fieldNum(FDcontractTable,
            ContractId)).value(queryValue('CNRT_004'));

    query.validTimeStateDateRange(contractStartDate, contractEndDate);

    queryRun = new QueryRun(query);

    if(queryRun.prompt())
    {
        while(queryRun.next())
        {
            FDcontractTable = queryRun.getNo(1);
            info(strFmt("%1: %2 - %3",
                FDcontractTable.ContractId,
                FDcontractTable.ValidFrom,
                FDcontractTable.ValidTo));
        }
    }
}

4. örneği çalıştırdığınızda Query ekranında yeni bir özellik olan Date options ile karşılaşacaksınız. Bu sekmeden 3 tip var. İsimlerinden de anlaşılacağı üzere birincisi şu andaki aktif kaydı verir. İkincisi girilen tarihteki aktif kaydı verir. Üçüncüsü ise aralıktaki aktif kayıtları verir.

Kodda kullanımı gayet güzel olmuş.

Selamlar.

Dynamics Ax 2012 DimensionProvider sınıfı

Merhaba

Ax 2012 ile finansal boyut yapısındaki bir çok değişiklikten eski yazılarımda bahsetmiştim. Boyut yapısındaki bu değişiklikler üzerine kodlarımızda boyutla işlem yapmamız gerektiğinde çok zorlanacağımız düşünmüştüm. Microsoft’taki arkadaşlarda aynı düşünceyi paylaşmışlar ki DimensionProvider sınıfını yazmışlar. Bu sınıf Query yapısında boyutla ilgili işlemleri yapmamızı kolaylaştırıyor ve bizi gereksiz bir çok Join ifadesinden kurtarıyor. Aşağıdaki örneği inceleyelim.

static void FD_AddDimensionRangeToCust(Args _args)
{
    Query                       query = new Query();
    QueryRun                    queryRun;
    QueryBuildDataSource        qbds;
    DimensionProvider           dimProvider = new DimensionProvider();
    CustTable                   custTable;
    ;

    qbds = query.addDataSource(tableNum(CustTable));

    dimProvider.addAttributeRangeToQuery(query, qbds.name(),
                        fieldStr(CustTable,DefaultDimension ),
                        DimensionComponent::DimensionAttribute,
                        "20",
                        "BusinessUnit", true );

    queryRun = new QueryRun(query);
    queryRun.prompt();

    while(queryRun.next())
    {
        CustTable = queryRun.get(tableNum(CustTable));
        info(strFmt("%1 ; %2 ; %3", CustTable.AccountNum ,
                    CustTable.name() , CustTable.DefaultDimension));
    }
}

Bu örnekte BusinessUnit boyutu 20 olan müşterileri listeleyen bir Query yazdım. DimensionProvider sınıfının bir çok metodu mevcut. İhtiyaç oldukça incelemek lazım.

Eski versiyonlarda bunu yazmak gayet  kolaydı çünkü boyut müşteri tablosunda dizi tipinde bir alan olarak bulunuyordu. Ax 2012′de ise tamamen farklı tablolarda tutulan bir veri artık. Bu yüzden 3-4 tablolu bir Join ifadesi yazmaktansa bu sınıfı kullanmak çok daha kolay.

Bu Query ifadesinin Select ile nasıl yazılabileceğini bir sonraki yazımda  ele alacağım.

Selamlar.

AX 2012 QueryHavingFilter özelliği (Having)

Merhaba

“QueryHavingFilter” bizim SQL de kullandığımız “Having” ifadesinin axtaki karşılığıdır. AX 2012 ile gelen bu özellik malesef şimdilik sadece “Query” yapısında kullanılabiliyor.

Aşağıdaki SQL ifadesini inceleyelim.

SELECT CURRENCY, COUNT(RECID) FROM CUSTTABLE
	GROUP BY CURRENCY 	HAVING COUNT(RECID) < 3

Bu ifade de istediğimiz sonuç müşteriye bağlı adedi 3 ten az olan para birimlerinin listesi.

Bu ifadenin Ax’taki karşılığı yoktu. Döngüde kontrol yapıp bunu tespit ediyorduk. Bu da performans açısından yanlış bir kullanımdı.

AX 2012 ile gelen QueryHavingFilter bu özelliği axa taşımış oldu.

Bir Query örneğiyle AX 2012 ‘de nasıl kullanabileceğimize bakalım.

Read more

AX 2012 addQueryFilter ile addRange arasındaki fark

Merhaba

addQueryFilter ax 2012 ile gelen bir yenilik.

addQueryFilter ile addRange arasındaki farkı anlamak için öncelikle SQL’de bir kaç örnek yapalım.

Sql’de basit bir join .

SELECT * FROM CUSTTABLE
            OUTER JOIN CUSTTRANS ON CUSTTRANS.CUSTACCOUNT = CUSTTABLE.ACCOUNTNUM

Bu join’e hareketlerin para birimi EUR olanlar diye bir kriter vermek istersen 2 seçeneğimiz var.

SELECT * FROM CUSTTABLE
            OUTER JOIN CUSTTRANS ON CUSTTRANS.CUSTACCOUNT = CUSTTABLE.ACCOUNTNUM
                   AND CUSTTRANS.CURRENCYCODE = 'EUR'

veya

SELECT * FROM CUSTTABLE
            OUTER JOIN CUSTTRANS ON CUSTTRANS.CUSTACCOUNT = CUSTTABLE.ACCOUNTNUM
                WHERE  CUSTTRANS.CURRENCYCODE = 'EUR'

Birinci sql ifadesi öncelikle CustTable da bulunan bütün kayıtları getirir. Hareketlerden de sadece EUR olanları alır.

İkinci ifade ise aslında inner joinin yaptığı işi yapar ve sadece EUR tipinde hareketi olan müşterileri ve hareketlerini getirir.

İşte addQueryFilter ile addRange arasındaki fark bu iki sql ifadesi arasındaki farkla birebir aynıdır.

addQueryFilter where ifadesini , addRange ise and ifadesine karşılık gelir.

Ax ta bir örnekle inceleyelim,

static void Query_addQueryFilter (Args _args)
{
    Query                   query;
    QueryBuildDataSource    qbdsCustTable , qbdsCustTrans;
    QueryBuildRange         range;
    QueryFilter             filter;
    QueryRun                qRun;    

    custTable               CustTable;
    custTrans               custTrans;
    ;

    query = new Query();
    qbdsCustTable = query.addDataSource(tableNum(CustTable));
    qbdsCustTrans = qbdsCustTable.addDataSource(tableNum(CustTrans));
    qbdsCustTrans.joinMode(JoinMode::OuterJoin);
    qbdsCustTrans.relations(true);       

    query.addQueryFilter(qbdsCustTrans,  fieldStr(CustTrans, CurrencyCode)).value(SysQuery::value('EUR'));

   // qbdsCustTrans.addRange(fieldNum(CustTrans, CurrencyCode)).value(SysQuery::value('EUR'));  

    qRun = new QueryRun(query);
    while (qRun.next())
    {
        CustTable = qRun.get(TableNum(CustTable));
        custTrans = qRun.get(TableNum(custTrans));        

        info(strfmt("%1 : %2: %3: %4", CustTable.AccountNum ,
                                                CustTable.name(),
                                                custTrans.AmountMST,
                                                custTrans.CurrencyCode
                                                ));
    }

}

addQueryFilter koddan çok formalarda kullanılmak üzere geliştirilmiş bir özellik. Formlardaki veri süzme işleminde artık varsayılan olarak addQueryFilter kullanılıyor.

Selamlar.

Prompt ekranından girilen kriterleri başka bir query’e aktarmak

Merhaba

Prompt ekranı bir query için kriter girme, sıralama ve gruplama gibi farklı işlemleri yapabileceğiniz çok esnek bir uygulamadır. Özellikle rapor ve formlarda çok kullanılan bu ekranı her ax kullanıcısının çok iyi bilmesi gerekir. Bizim bu yazıdaki konumuz Prompt ekranında herhangi bir veri kaynağı için dinamik olarak girilen kriterleri tespit edip başka bir query’e aktarmaktır.

Bunu şöyle bir jobta deneyebiliriz:


static void GetQueryPromtRangeValues(Args _args)
{
CustTable               CustTable;
CustTable               CustTable2;
int                     counter;

Query                   q;
QueryRun                qRun;
QueryBuildRange         qbr;
QueryBuildDataSource    qbds;

Query                   q2;
QueryRun                qRun2;
QueryBuildDataSource    qbds2;

QueryBuildRange         qbrGet;
QueryBuildDataSource    qbdsGet;

;
// Birinci Query
q       = new Query();
qbds    = q.addDataSource(TableNum(CustTable));
qRun    = new QueryRun(q);
// İkinci Query
q2       = new Query();
qbds2    = q2.addDataSource(TableNum(CustTable));

if(qRun.prompt())
{
// CustTable veri kaynağı için girilen kriterleri buluyoruz
qbdsGet = qRun.query().dataSourceTable(TableNum(CustTable));
counter = qbdsGet.rangeCount(); // Kaç adet kriter girilmiş tespit ettik
// Girilen kriterleri bir döngü kullanarak ikinci query ye ekliyoruz
while(counter >0)
{
qbrGet = qbdsGet.range(counter);
info(strfmt("%1 : %2 ",counter , qbrGet.value() ));
qbds2.addRange(qbrGet.field()).value(qbrGet.value());
counter--;
}

setPrefix("Asıl Query ile ");
while(qRun.next())
{
CustTable = qRun.get(TableNum(CustTable));
info(strfmt("%1 : %2 ", CustTable.AccountNum,CustTable.Name ));
}
}

// ikinci query için QueryRun oluşturuyoruz.
// Aynı kriterlerin eklendiğini promt ekranında görebiliyoruz
qRun2    = new QueryRun(q2);

setPrefix("İkinci Query ile ");
if(qRun2.prompt())
{
while(qRun2.next())
{
CustTable2 = qRun2.get(TableNum(CustTable));
info(strfmt("%1 : %2 ", CustTable2.AccountNum,CustTable2.Name ));
}
}
}

Selamlar.

ExistsJoin ve NotExistJoin ile Lookup yazmak

Merhaba

Şöyle bir istek olsun.  Seçilecek vergi numarası ne müşteri nede satıcı tablosunda kullanılmış olsun. Bu gibi bir istekte notexistjoin kullanabiliriz. Eğer müşteride veya satıcıda  kullanılanlar listelensin denseydi existjoin kullanacaktık.

client static void lookupETGVATNum (FormStringControl ctrl, Common common)
{
    SysTableLookup          sysTableLookup = SysTableLookup::newParameters(tablenum(TaxVATNumTable), ctrl);
    Query                   query = new Query();
    QueryBuildDataSource    queryBuildDataSource = query.addDataSource(tablenum(TaxVATNumTable));
    QueryBuildRange         queryBuildRange = queryBuildDataSource.addRange(fieldnum(TaxVATNumTable, CountryRegionId));
    QueryBuildDataSource    qdbs;
    ;

// CustTable müşteri tablosunda olmayanları getiriyoruz
    qdbs  = queryBuildDataSource.addDataSource(tablenum(CustTable));
    qdbs.addLink(fieldnum(TaxVATNumTable , vatNum ),fieldnum(CustTable , vatNum ));
    qdbs.joinMode(joinmode::NoExistsJoin);

Read more

Axaptada forma kodla çoklu range eklemek

Merhaba

Bir araç isteği geliştirmesi yaptığımızı düşünelim. Araç isteklerinin listelendiği bir form yapıyoruz.
Burada kişi bu formu açtığında kendi kayıtları ve kendisine bağlı olan pozisyondaki personelinin kayıtları görünsün istiyoruz.

init motudundan çağırabileceğimiz addrange metodumuz şöyle olabilir.

void addRange()
{

HRPPartyPositionTableRelationship HRPPartyPosition;
HRPPartyPositionTableRelationship HRPPartyPosition2;
QueryBuildRange rangeReqOwner;
emplId emplId;
str filterReqOwner;

;rangeReqOwner = VehicleRequest_ds.query().dataSourceTable(tablenum(VehicleRequest)).addRange(fieldNum(VehicleRequest, ReqOwner)); // range tanımlıyoruz

Read more

Query ile yapamadığınız bir join’i nasıl yapabilirsiniz?

Merhaba

BankAccountTable’ı lookup da açtırmak istiyoruz. Kriterlerimiz şöyle.

Lookupta  BankAccountTable.AssignedBankTransType alanı boş olanlar ve BankTransType.BankTransType   <>  BankAccountTable.AssignedBankTransType

İlişkisiyle  BankTransType’ın BankTransType.ExchangeNoteDocType’ı Çek ve senetten farklı olan kayıtlar isteniyor.

Query’de   bu join’in nasıl yapılacağını bulamadım.  Bu sebepten  temp tablo kullanmaya  karar verdim.  while select kullanarak temptabloyu doldurup.

Sonra lookup için query’ı yazdım.

Axaptada joinlerle ilgili bir makaleyi ilerki zamanlarda yayınlayacağım.

Örenk metod şöyledir.

 

static client void lookupPortfolioPromissory(FormStringControl _ctrl, CurrencyCode _filterStr)
{
    SysTableLookup                sysTableLookup = SysTableLookup::newParameters(tablenum(tmpBankAccountTable),_ctrl);
    Query                                     query = new Query();

Read more

Axapta’da arama metodu örneği

Merhaba

8 arama sahası ve 5 farklı tablo içeren bir arama formu istendiğinde nasıl bir metod yazabileceğinizin bir örneğini paylaşıyorum.

Hangi sahanın dolu olacağı belli olmayan ve kombinasyonun çok fazla olduğu bu durumda öncelikle en çok kriter girilebilecek

olan ana tabloyu alıp döngü içinde diğerlerinin varlığı kontrol etmek mantıklı.

Kriterlere uyan bir kayıt olursa bunun bir container a dolduruyoruz.

public Container simpleSearch(  BorAXEmplId  _boraxEmplId

                                ,EMplId _emplId

                                ,HRMIdentificationNumber _number

                                ,EmplName _name

                                ,HrmLastName _lastName

                                ,Birthdate _birthDate

                                ,NameTwenty _birthPlace

                                ,Email _email)

{

Read more

Lookup’ta join ile query yazmak

Merhaba

Axapta  formlarında bir alanın lookup metodunu ezmek zorunda kalabilirsiniz.

Örneğimizde bir lookup metedu var.  join ile query yazılıp kriter veriliyor.
static client void lookupPortfolioPromissory(FormStringControl _ctrl, CurrencyCode _filterStr)// para birimine göre farklı gelsin
{
    SysTableLookup          sysTableLookup = SysTableLookup::newParameters(tablenum(BankAccountTable),_ctrl);
    Query                   query = new Query();
    QueryBuildDataSource    queryBuildDataSource = query.addDataSource(tablenum(BankAccountTable)); // birinci tablomuz
    QueryBuildDataSource    qdbs;
    ;

Read more

Page 1 of 3123