Archive for the ‘ x++ ’ Category

Dynamics AX’ta BCC (Gizli) mail nasıl gönderilir?

Merhaba

Ax içinden Bcc mail göndermek için SYSMailer sınıfına bazı eklemeler yapmak gerekiyor.

Aşağıdaki metotları SYSMailer sınıfına ekleyelim.

//DMR FD
SysMailerAddressField bccs()
{
    InteropPermission permission = new InteropPermission(InteropKind::ComInterop);

    permission.assert();

    //BP Deviation Documented
    return SysMailerAddressField::create(_com,SysmailerAddressFieldType::Bcc);
}

.

// DMR FD
SysMailerAddressField tosBCC()
{
    ;
    return SysMailerAddressField::create(_com,SysmailerAddressFieldType::Bcc);
}

.

// DMR FD
public void quickSendBcc(str fromAddr, str toAddr, str subject,
 str body, str cc='',str bcc='', str attachments='')
{
    SysMailerAddressField tos;
    SysMailerAddressField ccs;
    SysMailerAddressField bccs;
    SysMailerAttachments mailAttachments;
    SysEmailParameters parameters;

    List emailAddresses;
    ListEnumerator enum;
    ;

    this.fromAddress(fromAddr);

    tos = this.tos();
    emailAddresses = SysEmailDistributor::splitEmail(toAddr);
    enum = emailAddresses.getEnumerator();
    while(enum.moveNext())
    {
        tos.appendAddress(enum.current());
    }

    this.subject(subject);
    this.htmlBody(body);

    if (!prmisdefault(cc))
    {
        ccs = this.ccs();
        ccs.appendAddress(cc);
    }

    if (!prmisdefault(bcc))
    {
        bccs = this.bccs();
        bccs.appendAddress(bcc);
    }

    if (!prmisdefault(attachments))
    {
        mailAttachments = this.attachments();
        mailAttachments.add(attachments);
    }

    this.priority(1);

    parameters = SysEmailParameters::find();

    if (parameters.smtpRelayServerName)
    {
        this.SMTPRelayServer(parameters.smtpRelayServerName,parameters.smtpPortNumber,
              parameters.smtpUserName,SysEmailParameters::password(),parameters.ntlm);
    }

    this.sendMail();

}

Bu eklemelerde sonra şöyle bir örnekle mail gönderimini test edebiliriz.

static void FD_SendMailSampleCcandBcc(Args _args)
{
    SysMailer   mailer;
    str         toEmail     = "fatih.demirci@aaaa.com";
    str         fromEmail   = "iletisim@aaaa.com";
    str         cc          = "aaaaa@aaaa.com";
    str         bcc         = "bbbb@aaaa.com";
    str         subject     = "Email konusu";
    str         body        = "Email içeriği";

    ;
    mailer = new SysMailer();
    mailer.quickSendBcc( fromEmail, toEmail, subject, body, cc , bcc);

}

Selamlar.

Proje teklif satırından otomatik WBS kaydı oluşturmak (AX 2012)

Merhaba

Ax 2012′de proje tekliflerini girerken teklif satırından otomatik WBS satırlarının oluşturulması için yazdığım metodu sizinle paylaşıyorum.

Bu metot sayesinden wbs ve teklif arasından etkileşimi sağlamış oluyoruz.

void addItemToWBS()
{
    PSAActivityEstimates    estimates;
    Hierarchy               hierarchy;
    HierarchyIdBase         hierarchyId;
    HierarchyTreeTable      hierarchyTreeTable;
    ;
    hierarchyId = HierarchyLinkTable::findRefTableRecId(tablenum(SalesQuotationTable),
                SalesQuotationTable.RecId).HierarchyId;
    hierarchyTreeTable   = HierarchyTreeTable::findbyNameonHierarchy(hierarchyId ,
           "FD_AnaKategori"); // Hangi kategoriye bağlanacak
    smmActivities      = smmActivities::find(hierarchyTreeTable.activityNumber());

    estimates.clear();
    estimates.ActivityNumber     = smmActivities.ActivityNumber;
    estimates.initFromInventTable(InventTable);
    estimates.InventDimId        = SalesQuotationLine.inventDimId;
    estimates.ItemId             = SalesQuotationLine.ItemId;
    estimates.ProjCategoryId     = SalesQuotationLine.ProjCategoryId;
    estimates.Quantity           = SalesQuotationLine.SalesQty;
    estimates.ProjTransType      = SalesQuotationLine.ProjTransType;
    estimates.Worker             = SalesQuotationLine.ProjectWorker;
    estimates.UnitSalesPrice     = SalesQuotationLine.SalesPrice;
    estimates.UnitCostPrice      = SalesQuotationLine.CostPrice;
    estimates.TotalSalesPrice    = SalesQuotationLine.LineAmount;
    estimates.TotalCostPrice     = SalesQuotationLine.SalesQty * SalesQuotationLine.CostPrice;
    estimates.LinePropertyId     = SalesQuotationLine.LinePropertyId;
    estimates.Description        = SalesQuotationLine.ProjDescription;
    estimates.PRGSalesUnit       = SalesQuotationLine.SalesUnit;
    estimates.insert();

    ttsBegin;
    SalesQuotationLine.selectForUpdate(true);
    SalesQuotationLine.PSARefRecId  = estimates.RecId;
    SalesQuotationLine.doUpdate();
    ttsCommit;

}

Update ve Delete kodları SalesQuotationLine içinde psaUpdateActivityEstimates() ve psaDeleteActivityEstimates() adiyla mevcut. Sistem bunları kullanıyor.

Selamlar.

Stok hareketine kodla rezervasyon koymak

Merhaba

Uzun zamandır fırsat bulup yeni yazı yazamıyordum. Canlıya geçiş yoğunlu sonra iş değişikliği derken zaman çok hızlı geçti. Yeni işimle birlikte farklı konularda da yazılar yazmayı planlıyorum.

Bu yazımda koddan bir stok hareketine nasıl rezervasyon koyulabileceğini anlatacağım.  Bu örnekte SalesLine’nın stok hareketi var ancak SalesQoutationLine gibi farklı tablolar da olabilir. Rezervasyonu eldeki stoğa veya satın almaya koyabilirsiniz. Formdan rezervasyon koymak için satış formunu açıp satırlardan / Stok/ Rezervasyon menüsünden açılan formda, Rezervasyon sütununa istediğiniz miktarı yazarak yapabilirsiniz.

Eğer bu işlemi koddan yapmak istersek aşağıdaki gibi bir kod işimizi görecektir.

  DMRSalesQuotationControl::inventReservation(Salesline.InventTransId ,
        "", SalesLine.SalesQty , false ,true);

Server Static void inventReservation(   InventTransId   _inventTransId,
                                           InventSerialId  _inventSerialId,
                                           Qty             _qty ,
                                           boolean         _unreserve = false ,
                                           boolean         _allowReserveOrdered = false)
{
    InventUpd_Reservation   inventUpd_Reservation;
    inventMovement          inventMovement;
    InventSerial            invserial;
    inventdim               inventDim,iDimNew;
    SalesLine               salesLine;
    ;
    ttsbegin;
    salesLine = SalesLine::findInventTransId(_inventTransId);
    if (!salesline)
    {
        throw error("Sales order line could not be found !");
    }
    inventDim                = salesLine.inventDim();
    inventdim.inventSerialId = _inventSerialId;
    iDimNew                  = inventDim::findOrCreate(inventDim);

inventMovement =InventTrans::findTransId(salesLine.InventTransId).inventMovement(true);
    if(inventMovement)
    {
        inventUpd_Reservation = InventUpd_Reservation::newInventDim(inventMovement,
               iDimNew, _unreserve ? _qty : -_qty);
        // if there is not enough inventory make rezervation from Purchase order.
        inventUpd_Reservation.parmAllowReserveOrdered(_allowReserveOrdered);
        inventUpd_Reservation.updateNow();
    }
    ttscommit;

}

Ax 2009 ve Ax 2012 aynı kod çalışıyor.

Selamlar.

Gönderme panosunda çalışan ismini göstermek.

Merhaba

AX 2012′de Hizmet yönetimi/ Gönderme panosu (SMADispatchBoard) formunda sadece çalışan kodu gösteriliyor. Kod üzerinde bir süre durursanız çalışanın adını da gösteriyor. Buradan iş ataması yapacak kişilerin bütün kodları bilmesi mümkün değil. Altyapı olarak ActiveX kullanıldığı için direk değiştiremiyoruz. Çalışan ismini göstermek için veriyi dolduran sınıfta ufak bir değişiklik yapmak gerekiyor.

GanttVcDataTable sınıfının  createUserDefinedRecord() metoduna  // FD aralığındaki kodu eklemek yeterli olacaktır.

        else
        {
            if(_mapInsertedFields && _mapInsertedFields.exists(ganttVcDataTableField.parmFieldName()))
            {
                strFieldValue = _mapInsertedFields.lookup(ganttVcDataTableField.parmFieldName());
                // FD
                if(HcmWorker::findByPersonnelNumber(strFieldValue))
                {
                    strFieldValue = HcmWorker::findByPersonnelNumber(strFieldValue).name() ;
                }
                // FD
            }
        }

Selamlar.

Dynamics Ax’ta bir metni başlık formatına (Title Case) çevirmek

Merhaba,

Basit bir hata sonucu axa aktarılan büyük bir verinin tamamen büyük harfle oluştuğunu gördüm. İlgili departman bu verinin başlık formatında olmasını istedi. Veriyi tekrar aktarmaktansa güncellemeyi daha doğru buldum . Ax’ta büyük ve küçük harfe çeviren metotlar var ancak başlık formatına (Title Case) çeviren bir metot yok . Bu yüzden .Net’ten yararlanarak bu işlemi yaptım. Örnek kod şu şekilde:

static void FD_ChangeCase(Args _args)
{
    System.String                       myString ;
    System.Globalization.TextInfo       TextInfo ;
    System.Globalization.CultureInfo    CultureInfo ;

    myString    = "PERAkeNDE SATIŞ TEksTİL SEgmENTİ";
    CultureInfo = new System.Globalization.CultureInfo("tr");
    TextInfo    = CultureInfo.get_TextInfo();

    info(  TextInfo.ToTitleCase(TextInfo.ToLower( myString ))) ;
    info(  TextInfo.ToLower( myString )) ;
   // info(strLwr("PERAkeNDE SATIŞ TEksTİL SEgmENTİ"));
    info(  TextInfo.ToUpper( myString )) ;
   // info(strUpr("PERAkeNDE SATIŞ TEksTİL SEgmENTİ"));

}

Selamlar.

Dynamics Ax’ta Regular expression kullanımına örnekler

Merhaba

Birinci örnekte metoda gönderilen metinin nokta(). ve tire(-)  haricinde özel karakter içerip içermediğini kontrol ediyoruz.

static boolean isProductNumberValid(EcoResProductNumber _ecoResProductNumber )
{
    Str MatchPattern ="[^a-zA-Z0-9\-.]";
    System.Text.RegularExpressions.Match myMatch;
    ;

    myMatch = System.Text.RegularExpressions.Regex::Match(_ecoResProductNumber,
                                 MatchPattern);

    return !myMatch.get_Success();

}

İkinci örnekte ise gönderilen metindeki özel karakterleri tire(-) ile değiştiriyoruz. Regex ile köşeli parantez “[ ]” ve ters sılaş “\” karakterlerini değiştiremedim. Bu yüzden ax’ın strReplace() metodunu kullanarak değiştirmek zorunda kaldım.

static EcoResProductNumber clearProductNumber(EcoResProductNumber _EcoResProductNumber)
{
    Str                 Pattern =  "[ :;,/+*'@_#!|$½%&(){}^~<> ]";
    EcoResProductNumber ecoResProductNumber;
    ;
ecoResProductNumber =System.Text.RegularExpressions.Regex::Replace(_EcoResProductNumber,
                                                        Pattern, "-");
    ecoResProductNumber = strReplace(ecoResProductNumber ,'[',"-");
    ecoResProductNumber = strReplace(ecoResProductNumber ,']',"-");
    ecoResProductNumber = strReplace(ecoResProductNumber ,'\\',"-");

    return  ecoResProductNumber;
}

Bu metodları Global sınıfına ekledim. Kullanımı çok basit.

static void SEC_FD_RegEx(Args _args)
{
    ;

    if(Global::isProductNumberValid("SEC.s-f.sdf."))
    {
        info("Kod doğru.");
    }

    info(Global::clearProductNumber("SEC D:;,/+*'@_#!|%&(){}^~[] "));
}

Selamlar.

Dynamics Ax 2012′de bir boyut nasıl zorunlu hale getirilir.

Merhaba

Ax 2012 ile değişen mali boyut yapısında herhangi bir boyutun nasıl zorunlu hale getirilebileceğine değineceğim.  Öncelikle General Ledger / Seturp /Configure account structures formunu açtığınızda aşağıda resimde göründüğü gibi alanın boş bırakılmasıyla ilgi parametre mevcut.

Bu parametre sadece deftere nakil işleminde çalışıyor. Örneğin yeni bir müşteri tanımlıyorsunuz ve departman boyutunun zorunlu olmasını istiyorsanız bu tanım bu işlemi yapmıyor.  Standartta böyle bir tanım yapılabiliyor mu diye araştırdım bulamadım. Validasyon yazmaktan başka bir çözüm bulamadım. Alanlarında boyut (DefaultDimension ) olan herhangi bir tablonun ValidateWrite() metodunu aşağıdaki gibi değiştirelim.

public boolean validateWrite()
{
    boolean ret;
    ;
    ret = super();

    if(!this.checkDimValue(5637144850)) // Must be parametric
    {
        ret =  checkFailed("Departman boyutu boş bırakılamaz.") && ret;
    }
    return ret;
}

Tabloya gerekli metodu ekleyelim.

Boolean checkDimValue(RefRecId _refRecId)
{
    DimensionAttributeValue             dimAttrValue;
    DimensionAttributeValueSetItem      dimAttrValueSetItem;

    ;

    select firstonly dimAttrValueSetItem
    where dimAttrValueSetItem.DimensionAttributeValueSet == this.DimensionDefault
    join dimAttrValue
        where dimAttrValue.RecId == dimAttrValueSetItem.DimensionAttributeValue
        &&    dimAttrValue.DimensionAttribute   == _refRecId ;

    if(dimAttrValueSetItem.DisplayValue)
        return true;
    else
        return false;

}

Selamlar.

Microsoft Dynamics AX 2012 Test Data Transfer Tool (beta)

Merhaba

Ax 2012′de değişen yapıyla birlikte ortamlar arasında veri transferi biraz sıkıntılı bir durum oldu. Örneğin canlı ortamın veri tabanı yedeğini alıp test ortamına yüklerseniz tamamen eşitlemiş oluyorsunuz. Geliştirmeler temel  ayarlar dahil. Bazen bunu da yapmak isteyebiliriz ama genelde sadece işle alakalı verilerin aktarılmasını isteriz. Bunu yapabilmek için InformationSource’ ta  Test Data Transfer Tool (beta) adında bir araç yayınlandı. Bu araçla ilgili ayrıntılı bilgiyi TechNet‘te bulabilirsiniz. Microsoft bu aracı sadece canlı ortamdan veri aktarmak için kullanmayı tavsiye ediyor. Canlı ortamın kendisine bu aracı kullanarak veri aktarmayı tavsiye etmiyor.

The Test Data Transfer Tool (beta) aşağıdaki durumlar için uygundur.

  • Büyük verileri veya birden çok şirketi içeren verileri içeri aktarmak veye dışarı aktarmak için.
  • Birbirinden çok farklı olmayan ax ortamları arasında veri aktarımı için.
  • Versiyon kontrol sistemi kullanıldığında.
  • Microsoft Dynamics AX Application Object Server (AOS) çalışmadan aktarım yapmak gerektiğinde.

The Test Data Transfer Tool (beta) veri aktarımı için Microsoft SQL Server bulk copy tool (bcp)’yi kullanıyor. Bu sayede işlemler SQL server üzerinden daha hızlı yapılabiliyor ve AOS’a ihtiyaç duymuyor. SQL üzerinde bu aktarım yaptığımız için veri bütünlüğü korunur. Örneğin RecID’lerde değişiklik yapmaz aynısını oluşturur.Hangi verinin dışarı aktarılacağı filtrelenebilir.

Aşağıda dışarı aktarım ve içeri aktarım işlemini özetleyen bir grafik var. Burada da görüleceği gibi 3 tane farklı dosya dışarı aktarılıyor. Bu dosyalar text bazlı olduğu için versiyon kontrolü bile yapılabilir.

İçeri aktarım işine mutlaka SQL Server’ın kurulu olduğu makinede admin yetkisiyle yapmak gerekiyor.

Ax 2012 ile veri aktarımı için bir çok alternatif geldi. Bunların hangisi hangi durum için en uygun çözüm olduğunu anlatan bir makaleyi ilerde yazacağım.

Selamlar.

X++ ile Vergi Kimlik Numarası kontrolü nasıl yapılır

Merhaba

Vergi kimlik numarasının bir algoritması var. Bu algoritma sayesinde girilen numaranın geçerli olup olmadığını tespit edebilirsiniz. Bu kontrolü yapacak bir fonksiyona ihtiyacım vardı. İnternette farklı dillerde yazılmış bir çok örnek buldum ancak X++ ile yazılmış bulamadım. Global sınıfına vergiKimlikNoValidation_FD adında bir metot yazdım.


// FD : Vergi kimlik no doğrulama
private boolean vergiKimlikNoValidation_FD(int64 kno)
{
    int     lastDigit;
    int     total = 0;
    int     i ;
    int     j = 1000000000;
    int     dig;
    int     v1 , v11;
    ;

    if (strLen(int2str(kno)) != 10)
        return   false;

    lastDigit = kno mod 10;

    for (i = 9; i >= 1; i--)
    {
        dig = (kno div j) mod 10 ;
        j = j / 10 ;
        if (dig < 0)
            return  false;
        v1  = ((dig + i) mod 10);
        v11 = (v1 * power(2, i)) mod 9;
        if (v1 != 0 && v11 == 0)
            v11 = 9;
        total += v11;
    }

    if (total mod 10 == 0)
        total = 0;
    else
        total = (10 - (total mod 10));

    if (total == lastDigit)
        return  true;
    else
        return  false;
}

Selamlar.

How to release products to all companies.

Hi,

As you know with Dynamics AX 2012, you have to create a product first and then release to the product to companies. You can release which company do you want. In my company there is a request to release product all companies automaticly. I have some research and found good post and methods about it. I wrote a class named SECReleaseProductForAllCompanies and make it MenuItemButton as you can see below.

Let see methods of class now.

Class decleration;

// FD Relaese products for all companies
class SECReleaseProductForAllCompanies
{
    EcoResProductDisplayProductNumber   productNumber;
    EcoResProduct                       ecoResProduct;
}

Main method; Gets all the selected records and calls run.

public static void main(Args args)
{
    SECReleaseProductForAllCompanies    releaseProductForAllCompanies;
    ecoResProduct                       EcoResProduct;
    FormDataSource                      fdsEcoResProduct;
    ;

    fdsEcoResProduct = args.record().dataSource();
    for (EcoResProduct = fdsEcoResProduct.getFirst(true) ? fdsEcoResProduct.getFirst(true) :
            fdsEcoResProduct.cursor();   EcoResProduct; EcoResProduct = fdsEcoResProduct.getnext())
    {
        releaseProductForAllCompanies = new SECReleaseProductForAllCompanies();
        releaseProductForAllCompanies.parmProductNumber(ecoResProduct.DisplayProductNumber);
        releaseProductForAllCompanies.run();

        info(strfmt("%1  %2 product successfully released to all companies. ",
                    EcoResProduct.productNumber() , EcoResProduct.productName() ));
    }
}

Parm method;

public EcoResProductDisplayProductNumber parmProductNumber(
            EcoResProductDisplayProductNumber _productNumber = productNumber)
{
    productNumber = _productNumber;

    return productNumber;
}

Run method;

private void run()
{
    ;
    this.releaseProduct();
}

Release method; You can use EcoResProductReleaseManagerBase::releaseProduct() static method instead of this.

private void releaseProduct()
{
    InventTable                 inventTable;
    InventTableModule           inventTableModule;
    NumberSequenceTable         numberSequenceTable;
    ItemId                      itemId;
    InventItemSetupSupplyType   inventItemSetupSupplyType;
    CompanyInfo                 companyInfo;

    EcoResStorageDimensionGroupProduct  ecoResStorageDimensionGroupProduct;
    EcoResTrackingDimensionGroupProduct ecoResTrackingDimensionGroupProduct;
    EcoResStorageDimensionGroupItem     ecoResStorageDimensionGroupItem;
    EcoResTrackingDimensionGroupItem    ecoResTrackingDimensionGroupItem;
    ;

    select firstOnly ecoResProduct
        where EcoResProduct.DisplayProductNumber == productNumber;

    while select companyInfo
        where companyInfo.DataArea != "DAT"
    {
        changecompany (companyInfo.DataArea)
        {
            ttsBegin;
            inventTable = null;
            inventTableModule = null;
            inventItemSetupSupplyType = null;
            ecoResStorageDimensionGroupProduct = null;
            ecoResTrackingDimensionGroupProduct = null;
            ecoResStorageDimensionGroupItem = null;
            ecoResTrackingDimensionGroupItem = null;

            numberSequenceTable = InventParameters::numRefItemId().numberSequenceTable();

            if (!numberSequenceTable.RecId || numberSequenceTable.Manual)
            {
                itemId = ecoResProduct.productNumber();
            }
            else
            {
                itemId = NumberSeq::newGetNumFromId(numberSequenceTable.RecId).num();
            }

            inventTable.initValue();
            inventTable.initFromEcoResProduct(ecoResProduct);
            inventTable.ItemId = ItemId;
            inventTable.NameAlias = ecoResProduct.SearchName;
            inventTable.insert(true);

            inventTableModule.initValue();
            inventTableModule.ItemId = inventTable.ItemId;
            inventTableModule.ModuleType = ModuleInventPurchSales::Invent;
            inventTableModule.insert();

            inventTableModule.initValue();
            inventTableModule.ItemId = inventTable.ItemId;
            inventTableModule.ModuleType = ModuleInventPurchSales::Purch;
            inventTableModule.insert();

            inventTableModule.initValue();
            inventTableModule.ItemId = inventTable.ItemId;
            inventTableModule.ModuleType = ModuleInventPurchSales::Sales;
            inventTableModule.insert();

            InventItemLocation::createDefault(inventTable.ItemId);

            inventItemSetupSupplyType.initValue();
            inventItemSetupSupplyType.ItemId = inventTable.ItemId;
            inventItemSetupSupplyType.ItemDataAreaId = inventTable.DataAreaId;
            inventItemSetupSupplyType.insert();

            ecoResStorageDimensionGroupProduct  = EcoResStorageDimensionGroupProduct::findByProduct(ecoResProduct.RecId);
            ecoResTrackingDimensionGroupProduct = EcoResTrackingDimensionGroupProduct::findByProduct(ecoResProduct.RecId);

            if (ecoResStorageDimensionGroupProduct.RecId)
            {
                ecoResStorageDimensionGroupItem.ItemDataAreaId = inventTable.DataAreaId;
                ecoResStorageDimensionGroupItem.ItemId = inventTable.ItemId;
                ecoResStorageDimensionGroupItem.StorageDimensionGroup = ecoResStorageDimensionGroupProduct.StorageDimensionGroup;
                ecoResStorageDimensionGroupItem.insert();
            }

            if (ecoResTrackingDimensionGroupProduct.RecId)
            {
                ecoResTrackingDimensionGroupItem.ItemDataAreaId = inventTable.DataAreaId;
                ecoResTrackingDimensionGroupItem.ItemId = inventTable.ItemId;
                ecoResTrackingDimensionGroupItem.TrackingDimensionGroup = ecoResTrackingDimensionGroupProduct.TrackingDimensionGroup;
                ecoResTrackingDimensionGroupItem.insert();
            }

            ttsCommit;

        }
    }
}


You can download class from here.

Thanks Sreenath Reddy G. for methods.

Until next time.

Page 2 of 151234510...Last »