Archive for the ‘ Dynamics AX ’ Category

Dynamics AX 2012 Caching 2

Merhaba

Ön bellek yapısından bahsetmeye CacheLookup özelliği ile devam edelim. Tablo özelliği olan CacheLookup bir verinin nasıl ön bellekleneceğini belirler. 5 farklı tip mevcut tek tek inceleyelim.

  1. None : Bu tipteki tablolarda veri ön belleğe alınmaz. Çok nadir durumlar dışında tabloda kullanılmamalıdır.  Eğer tabloda çok sık veri güncellemesi oluyorsa düşünülebilir. CustTrans gibi bir tablonun bile None olmadığını burada belirtmem gerekiyor.
  2. NotInTTS : Bütün anahtarlar için ön bellekleme çalışır. Bir işlem kümesinin dışında (TTSBegin öncesinde) oluşan ön bellek kullanılmaz. İşlem kümesinde bir kere okunan veri öne belleğe alının ve küme içerisinde bellekten kullanılır. Kayıt Select-Locked olarak çekildiği için işlem kümesinde güncellenmesi engellenir. Ax’taki bir çok hareket tablosu bu tiptedir. CustTrans gibi.
  3. Found :  Bütün anahtarlar için ön bellekleme yine çalışır. Kayıt çekildiğinde eğer ön bellekte varsa ön bellekten gelir. Yoksa veri tabanına bakılır. Eğer Forupdate ile select yapılırsa yine veri tabanına bakılır. Genelde ana tablolar bu tiptedir. CustTable gibi.
  4. FoundAndEmpty : Found ile aynı işi yapar ek olarak sorgu  ile gelmeyen veri tabanında olmayan kayıtları da ön bellekte tutar bu sayede olmayan bir kayıt için sürekli veri tabanına sorgu göndermez. CustInterestVersion gibi.
  5. EntireTable : Set-Base Caching te ayrıntılı anlatacağım. Kısaca bütün veriyi sunucuda ön belleğe alır.  Çok nadir güncelleme olan tablolarda kullanılabilir.  InventModelGroup gibi.

Inside Microsoft Dynamics Ax 2012 kitabından bazı örnekleri inceleyelim: Öncelikle NotInTTS

static void NotInTTSCache(Args _args)
{
CustTable custTable;
;
select custTable where custTable.AccountNum == '1101';
// Ön belleğe bakılır yoksa veri tabanından  getirilir.

ttsBegin; // İşlem Kümesi başlatıldı
select custTable where custTable.AccountNum == '1101';
// Ön bellek geçerli değili.  Veri tabanından getirilir ve ön belleğe alınır.

select forupdate custTable where custTable.AccountNum == '1101';
// Yine veri tabanından getirlir. Forupdate kullanıldığı için

select custTable where custTable.AccountNum == '1101';
// Ön bellek kullanılır

select forupdate custTable where custTable.AccountNum == '1101';
// Ön bellek kullanılır çünki önceden  forupdate kullanıldı.

ttsCommit; // işlem kümesi sonu.
select custTable where custTable.AccountNum == '1101';
// Ön bellek kullanılır.
}

Eğer tablo tipi Found veya FoundAndEmpty olsaydı işlem kümesinin hemen altındaki sorgu ön bellekten gelecekti. İlk forupdate içeren sorgu yine veri tabanından gelecekti. Başka bir örnekle devam edelim.

static void UtilizeCache(Args _args)
{
CustTable custTable;
;
select custTable where custTable.AccountNum == '1101';
// Ön bellek kullanılır çünki birincil anahtar kriter olarak verilmiş.

select custTable; // Where ifadesi olmadığı için ön bellek kullanılmaz.

select custTable where custTable.AccountNum > '1101';
// (==) kullanılmadığı için ön bellek kullanılmaz.

select custTable  where custTable.AccountNum == '1101'
                            && custTable.CustGroup == '20';
// Ön bellek kullanılır.
}

Tekil dizine ek olarak verilen kriterlerde Ax 2012 nasıl davranıyor bakalım.

static void whenRecordDoesGetCached(Args _args)
{
CustTable custTable,custTable2;
;
// CustTable found olduğunu hatırlatayım.
// Aşağıdaki sorgu sonucunda veri tabanında böyle bir kayıt olmadığı için
// ön belleğe alınamayacak.
// Eğer CustTable FoundAndEmpty tipinde olsaydı
// bulunamayan kayıtta ön belleğe alınacaktı.

select custTable where custTable.AccountNum == '1101'
                           && custTable.CustGroup == '20';
// Aşağıdaki ifade kayıdı ön belleğe alır.
select custTable  where custTable.AccountNum == '1101';
// Bu ifade kaydı ön belleğe alacaktır.
select custTable2 where custTable2.AccountNum == '1101'
                                && custTable2.CustGroup == '10';
// Eğer kodu tekrar çalıştırırsak bütün kayıtlar ön bellekten gelecek.
}

Şimdilik bu kadar.

Selamlar.

Kaynaklar : Inside Microsoft Dynamics Ax 2012 ve MSDN

Dynamics AX 2012 Caching 1

Merhaba,

AX 2012′deki ön bellek (cach) yapısıyla ilgili bir kaç konuyu ele almayı planlıyorum.  Bir çok yapıda olduğu gibi ön bellek yapısı da AX 2012 ile birlikte geliştirilmiş ve yeni özellikler eklenmiş.

AX iki tip ön bellek yapısı destekliyor. Single-Recod Caching ve Set-Based Caching. AX ile çalışırken biz hangi ön bellek yapısının kullanıldığını önemsemeyiz sistem sizin yazdığınız koda göre en uygunu bulup kullanır. Bizim performanslı bir sistem kurabilmek için bu yapıları iyi kavramamız gerekiyor.

Single-Recod Caching (Kayıt bazlı ön bellekleme)

Üç tip kayıt bazlı ön bellek mevcut. Eski versiyondan da bildiğiniz gibi bunlar NotInTTS, Found, FoundAndEmpty. Tablo üzerindeki CacheLookup özelliğinden tanımlama yapıyoruz.  Ön belleğin  bir select ifadesinde çalışabilmesi için öncelike;

  1. CacheLookup tanımlı olmalı.
  2. Record-Buffer (Tablo değişkeni ) disableCache metodu false olmalı.
  3. Where ifadesinde tekil dizin (unique index) olmalı tekil dizin dışında bir karşılaştırma kullanılırsa ön bellek çalışmaz.
  4. Karşılaştırma “==” kullanılmalı. >=, <=,  >  gibi ifadelerde ön bellek çalışmaz.

Ön bellek hem istemcide (client) hem de sunucuda (server) olabilir. AX çalışma zamanında ön belleği duruma göre yeniler. istemcideki ön bellek sadece kendi tarafından kullanılabilir. İstemcideki  ön bellek  istemcide çalışacak bir select ifadesinde kullanılır. Sistem öncelikle istemciye bakar burada bulamazsa sunucuya orada da bulamazsa veri tabanına bakar. Kaç kaydın ön bellekte tutulacağını server configuration formundan tanımlayabilirsiniz. Eski versiyonlarda bu 100 olarak geliyordu ve değiştirilemiyordu. Forma System administration > Area page > Setup > System > Server configuration yolundan ulaştıktan sonra Performance Optimization > Performance Settings > Client record cache factor kısmından tanım yapabilirsiniz.

Sunucu ön belleği de sunucuda çalışan select ifadelerinde kullanılır. En çok kaç kaydın ön belleğe alınacağının tanımını Server configuration ‘daki  Cache Limits alanından yapabilirsiniz. 2000 tanımlı olarak geliyor.

Ön bellek tanımları tek bir AOS için yapılacağı gibi birden çok AOS olan durumlarda her bir AOS için farklı farklı da yapılabilir.

AX 2012 ile gelen özelliklere bakalım.

  • Select’te ifadesinde kullanılan where ifadesinde tekil dizine && ile ilave kriter eklenebilir. || ile yapılan eklemelerde ön bellek çalışmaz. select * from tabCustTable where tabCustTable.AccountNum == “4000″ &&tabCustTable.CustGroup == “Gold”;
  • Join de öne bellek çalışır. Where ifadesi yine tekil dizine uygun olmalı.  Select from tabCustTable join tabCustGroup
    where tabCustTable.AccountNum == “4000″ && tabCustTable.CustGroup == tabCustGroup.CustGroup;
  • Eğer tek bir şirket işin içindeyse CrossCompany anahatar sözcüğünde de ön bellek desteklenir.
  • Eğer Container bir alanınız tekil dizindeyse ön bellek desteklenir.
  • Tablo kalıtımında (Table inheritance ) ön bellek desteklenir.
  • Tarih kontrollü (Valid time state)  tablolarda ön bellek desteklenir.

Şimdilik bu kadar. Sonraki yazımda CacheLookup özelliğini anlatacağım.

Selamlar.

Kaynaklar :  Inside Microsoft Dynamics Ax 2012 ve MSDN

FirstOnly1, FirstOnly10, FirstOnly100 ve FirstOnly1000 artık çalışıyor.

Merhaba

AX 2012′den önceki versiyonlarda da FirstOnly’nin versiyonları mevcuttu ancak Sql Server kullanıldığında çalışmıyordu Oracle’da çalıştığı söyleniyordu ancak  ben hiç deneyemedim. Artık AX 2012 ile Oracle desteği kalktı fakat bu fonksiyonları kaldırmamışlar. Select ifadelerinde çalışır hale getirmişler. Bu arada Query yapısında bu fonksiyonlar desteklenmiyor sadece FirstOnly kullanabiliyorsunuz.  X++’ ta limit gibi bir fonksiyonun olmaması büyük eksiklik ancak bu fonksiyonlar da yeri geldiğinde işe yarayabilir.  Şöyle bir örnek yazdım:

static void FD_FirstOnly(Args _args)
{
    VendTrans   vendTrans;
    int i = 1;
    ;
    while select firstOnly10 vendTrans
    {
        info(strfmt("%1 = %2 : %3  ",
                    i,
                    vendTrans.AccountNum ,
                    vendTrans.AmountCur     ));
        i++;
    }
}

Selamlar

AX’ta kod ile muhasebe günlüğünü deftere nakletmek

Merhaba

Kod ile muhasebe günlüğü oluşturmayı şu yazımda anlatmıştım. Oluşturulan günlüğü kod ile deftere nakletmek için aşağıdaki kodu kullanabilirsiniz.

static void FD_PostLedgerJournal(Args _args)
{
LedgerJournalCheckPost  ledgerJournalCheckPost;
LedgerJournalTable      ledgerJournalTable;
;
ledgerJournalTable      = LedgerJournalTable::find('000343_040');
ledgerJournalCheckPost  = LedgerJournalCheckPost::newLedgerJournalTable(
ledgerJournalTable,
NoYes::Yes);
ledgerJournalCheckPost.run();

}

Selamlar.

Etiket(Label)’te yeni satır kodu(\n) kullanmak

Merhaba

İnternette dolaşırken strFmrtLB() adında bir metoda rastladım. Ne işe yaradığını bir örnekle açıklamaya çalışacağım.
Şöyle bir metinimiz olsun. “Aşağıdaki parametreler yanlış Lütfen düzeltip tekrar deneyiniz.\nAmbar %1\nTesis %2 “
Bu metini etiket haline getirelim. Etiket kodu da @AIP6 olsun.

box::stop(strfmt(“@AIP6″,”Üretim”,”Depo1″));

Çıktısı:

İstediğimiz çıktıya ulaşamadık. Şimdi  strFmtLB() motodu ile tekrar deneyelim.

box::stop(strfmt(strFmtLB(“@AIP6″),”Üretim”,”Depo1″));

Çıktısı:

İsteğimiz çıktıya ulaştık. Umarım işinize yarar.

Selamlar.

Genel muhasebe yapısındaki değişiklikler

Merhaba

Ax 2012′den önceki versiyonlarda muhasebe iki ana tablodan oluşuyordu. Birincisi hesap planının tutulduğu LedgerTable . İkincisi muhasebe hareketlerinin tutulduğu LedgerTrans. Bu iki tablo muhasebe için en temel tablolardı. Bütün hareketler bu tabloda tutulur ve bir hesabın bakiye toplamı gibi işlemler için LedgerTrans üzerinde işlem yapmak yeterli olurdu. Ayrıca LedgerTrans’ın özeti olan bir toplam tablomuz vardı buda  LedgerBalancesDimTrans tablosuydu. Bunlara ek olarak boyut yapısı vardı. Boyut bir diziydi. Dimensions alanından yönetiliyordu. Firmanın ihtiyacına göre kaç boyut kullanacağı tespit edilir ve tanımlanırdı. Boyut sayısı lisansa bağlıydı.

Bu yapı ax 2012 ile tamamen değişmiş durumda. LedgerTable ve LedgerTrans tabloları yok.  LedgerTable yerine MainAccount tablosu var. Eskiden bir şirket için tek bir hesap planı tanımlanırken şimdi birden çok hesap planı tanımlamak mümkün. LedgerChartOfAccounts tablosu hesap planlarının tanımlandığı ana tablo. Bir hesap için select yazarken hangi ChartofAccount olduğunu da belirtmek gerekiyor.

Gelelim LedgerTrans tablosunun yapısına. Eski versiyonlarda  110110 hesabının 02.03.2012 tarihindeki deki hareketlerini bulmak için şöyle bir sorgu yeterliydi.


while select ledgerTrans

where ledgerTrans.AccountNum == “110110”  &&

ledgerTrans.TransDate       == 02\03\2012 &&

ledgerTrans.OperationsTax == OperationsTax::Current

{

İnfo(“...”)

}

Ax 2012 de ise şöyle bir sorgu yazmak gerekiyor.


static void FD_LedgerTrans1(Args _args)
{
MainAccount                         mainAccount;
GeneralJournalEntry                 generalJournalEntry;
GeneralJournalAccountEntry          generalJournalAccountEntry;
DimensionAttributeValueCombination  dimAttrValueComb;
SubledgerVoucherGeneralJournalEntry subledgerVoucherGeneralJournalEntry;

while select AccountingCurrencyAmount, TransactionCurrencyAmount,
TransactionCurrencyCode

from generalJournalAccountEntry

join dimAttrValueComb
where dimAttrValueComb.RecId == generalJournalAccountEntry.LedgerDimension
join AccountingDate, JournalNumber from generalJournalEntry
where generalJournalAccountEntry.GeneralJournalEntry == generalJournalEntry.RecId
&& generalJournalEntry.AccountingDate == 02\03\2012
&& generalJournalEntry.PostingLayer == OperationsTax::Current
&& generalJournalEntry.Ledger == Ledger::current()
join MainAccountId, Name from mainAccount
where mainAccount.RecId == dimAttrValueComb.MainAccount
&& mainAccount.MainAccountId == '110110'
join subledgerVoucherGeneralJournalEntry
where subledgerVoucherGeneralJournalEntry.GeneralJournalEntry == GeneralJournalEntry.RecId
{
info(strFmt("%1-%2 - %3 - %4 - %5 - %6 - %7 - %8 - %9",
mainAccount.MainAccountId, mainAccount.Name,
generalJournalEntry.AccountingDate,
subledgerVoucherGeneralJournalEntry.Voucher,
generalJournalAccountEntry.TransactionCurrencyCode,
generalJournalAccountEntry.TransactionCurrencyAmount,
generalJournalAccountEntry.AccountingCurrencyAmount,
generalJournalEntry.JournalNumber,
dimAttrValueComb.DisplayValue ));
}

}

Sorguda görüldüğü gibi LedgerTrans tablosu 5 tabloya bölünmüş durumda. Günlükler için  bir kaç tabloya daha ihtiyaç olduğunu ve onlarında bu sorguya duruma göre ilave edilmese gerektiğini unutmadan söyleyeyim.

Aşağıdaki resimde  ax 2012′deki muhasebe veri yapısı mevcut. Bu yapıyı iyi kavramak üzerinde yeni gelen boyut yapısını öğrenmek geliştirme yapabilmek için şart.

Selamlar.

Şirketin standart para birimini bulmak

Merhaba

Ax 2012 den önce şirketin standart para birimi için şu kodu kullanıyorduk.

CompanyInfo::find().CurrencyCode;

Ax 2012 ‘ de ise şu kodu kullanıyoruz.

Ledger::findByLegalEntity(CompanyInfo::find().RecId).AccountingCurrency;

Ax 2012 de şirketler Legal Entity olarak tanımlanıyor. Bu kısımlar tamamen yeni bir yapıda özellikle hesap planı ve muhasebe kayıtlarını tutulduğu yapı tamamen değişmiş. Başka bir yazımda muhasebe satırlarının yeni yapısı hakkında bilgi vereceğim.

Selamlar.

Microsoft Dynamics® AX 2012 Development Introduction sertifikası

Merhaba

AX 2012 için ilk sertifikamı aldım. “MB6-869 Microsoft Dynamics® AX 2012 Development Introduction”.

Dev I ve Dev II yi kapsayan bu sınavda 74 soru mevcut. 3 saate yakın süreniz var. Süre fazlasıyla yetiyor. Bir çok soru eski versiyondan bildiğimiz konulardan çıkıyor. AX 2012 ile gelen yeniliklerden de soru mevcut tabiki .Özelikle ListPage ve güvenlikle ilgili kısımlara çalışmak lazım. Dev I ve Dev II dokümanını iyice okuyup örnekler yapılırsa bu sınav kolaylıkla  geçilebilir.

Bu sertifikayı almak isteyen olursa yardımcı olabilirim.

Selamlar.

AX 2012 QueryHavingFilter özelliği (Having)

Merhaba

“QueryHavingFilter” bizim SQL de kullandığımız “Having” ifadesinin axtaki karşılığıdır. AX 2012 ile gelen bu özellik malesef şimdilik sadece “Query” yapısında kullanılabiliyor.

Aşağıdaki SQL ifadesini inceleyelim.

SELECT CURRENCY, COUNT(RECID) FROM CUSTTABLE
	GROUP BY CURRENCY 	HAVING COUNT(RECID) < 3

Bu ifade de istediğimiz sonuç müşteriye bağlı adedi 3 ten az olan para birimlerinin listesi.

Bu ifadenin Ax’taki karşılığı yoktu. Döngüde kontrol yapıp bunu tespit ediyorduk. Bu da performans açısından yanlış bir kullanımdı.

AX 2012 ile gelen QueryHavingFilter bu özelliği axa taşımış oldu.

Bir Query örneğiyle AX 2012 ‘de nasıl kullanabileceğimize bakalım.

Read more

AX 2012 addQueryFilter ile addRange arasındaki fark

Merhaba

addQueryFilter ax 2012 ile gelen bir yenilik.

addQueryFilter ile addRange arasındaki farkı anlamak için öncelikle SQL’de bir kaç örnek yapalım.

Sql’de basit bir join .

SELECT * FROM CUSTTABLE
            OUTER JOIN CUSTTRANS ON CUSTTRANS.CUSTACCOUNT = CUSTTABLE.ACCOUNTNUM

Bu join’e hareketlerin para birimi EUR olanlar diye bir kriter vermek istersen 2 seçeneğimiz var.

SELECT * FROM CUSTTABLE
            OUTER JOIN CUSTTRANS ON CUSTTRANS.CUSTACCOUNT = CUSTTABLE.ACCOUNTNUM
                   AND CUSTTRANS.CURRENCYCODE = 'EUR'

veya

SELECT * FROM CUSTTABLE
            OUTER JOIN CUSTTRANS ON CUSTTRANS.CUSTACCOUNT = CUSTTABLE.ACCOUNTNUM
                WHERE  CUSTTRANS.CURRENCYCODE = 'EUR'

Birinci sql ifadesi öncelikle CustTable da bulunan bütün kayıtları getirir. Hareketlerden de sadece EUR olanları alır.

İkinci ifade ise aslında inner joinin yaptığı işi yapar ve sadece EUR tipinde hareketi olan müşterileri ve hareketlerini getirir.

İşte addQueryFilter ile addRange arasındaki fark bu iki sql ifadesi arasındaki farkla birebir aynıdır.

addQueryFilter where ifadesini , addRange ise and ifadesine karşılık gelir.

Ax ta bir örnekle inceleyelim,

static void Query_addQueryFilter (Args _args)
{
    Query                   query;
    QueryBuildDataSource    qbdsCustTable , qbdsCustTrans;
    QueryBuildRange         range;
    QueryFilter             filter;
    QueryRun                qRun;    

    custTable               CustTable;
    custTrans               custTrans;
    ;

    query = new Query();
    qbdsCustTable = query.addDataSource(tableNum(CustTable));
    qbdsCustTrans = qbdsCustTable.addDataSource(tableNum(CustTrans));
    qbdsCustTrans.joinMode(JoinMode::OuterJoin);
    qbdsCustTrans.relations(true);       

    query.addQueryFilter(qbdsCustTrans,  fieldStr(CustTrans, CurrencyCode)).value(SysQuery::value('EUR'));

   // qbdsCustTrans.addRange(fieldNum(CustTrans, CurrencyCode)).value(SysQuery::value('EUR'));  

    qRun = new QueryRun(query);
    while (qRun.next())
    {
        CustTable = qRun.get(TableNum(CustTable));
        custTrans = qRun.get(TableNum(custTrans));        

        info(strfmt("%1 : %2: %3: %4", CustTable.AccountNum ,
                                                CustTable.name(),
                                                custTrans.AmountMST,
                                                custTrans.CurrencyCode
                                                ));
    }

}

addQueryFilter koddan çok formalarda kullanılmak üzere geliştirilmiş bir özellik. Formlardaki veri süzme işleminde artık varsayılan olarak addQueryFilter kullanılıyor.

Selamlar.

Page 7 of 20« First...567891020...Last »